Godot

← Intégrer le contenu à votre jeu

Godot 4.x · GDScript

Commencez par afficher une seule phrase. Ce petit exemple lit directement les données exportées de La clé du port ; il ne constitue pas un système de dialogue complet. Reliez ensuite ces données à l’interface de votre jeu.

1 · Préparer les fichiers et la scène

Créez une scène avec un nœud racine Label et enregistrez-la. Placez l’export complet du port dans res://story/. Attachez FirstText.gd au Label, puis lancez la scène avec F6.

story.json · Comprendre les fichiers exportés

2 · Afficher le premier texte

extends Label

const TEXT_ID = "fd7b61a3-8233-4ba7-8f77-b88b119a91bf"
var story: Dictionary

func _ready() -> void:
    var parser = JSON.new()
    var error = parser.parse(FileAccess.get_file_as_string("res://story/story.json"))
    if error != OK or not parser.data is Dictionary:
        text = "Cannot read story/story.json"
        return
    story = parser.data
    show_language("en")

func show_language(locale: String) -> void:
    var record: Dictionary = story["content"]["texts"][TEXT_ID]
    var translation: Dictionary = story["content"]["translations"].get(locale, {}).get(TEXT_ID, {})
    var message: Dictionary = translation.get("message", record["sourceMessage"])
    var line := ""
    for segment in message["segments"]:
        if segment["kind"] != "text":
            text = "This example needs text-only segments"
            return
        line += segment["text"]
    text = line

Résultat attendu : « Welcome to the harbour. I am Mira. » Avec locale = "de" ou le paramètre de langue de : « Willkommen im Hafen. Ich bin Mira. » Une langue absente utilise le texte source. Cet exemple prend en charge les segments de texte ; il ne supprime pas silencieusement les paramètres de substitution.

3 · D'une phrase à une conversation

L’identifiant de texte fixe ci-dessus sert au premier test. Dans votre jeu, choisissez flowRef/entryRef dans story-index.json, puis lisez execution.entries[entryRef].nodeRef et execution.nodes[nodeRef]. Le dialogue courant fournit text.textRef et speakerRef. La suite dépend du champ kind du nœud.

Nom et dialogue : Label.text. Réponses : Button.text et le signal pressed, en conservant l’identifiant de l’option. End : masquez le conteneur Control commun avec hide(). Dans l’exemple, show_language("de") change la langue du même texte sans passer au nœud suivant.

1. Continue et End : suivre les connexions et fermer la boîte de dialogue
2. Choix : identifiant, ordre et suite de la réponse sélectionnée
3. Conditions et variables : dix ou deux pièces d’or
4. Langue : mêmes identifiants, contenu relu dans la langue choisie
5. Command : donner un objet ou ouvrir une boutique
6. Call/Return : appeler une sous-histoire puis revenir

# story is the Dictionary loaded above. These Harbour options have no conditions.
var choice: Dictionary = story["execution"]["nodes"]["42edfff8-b8fe-46bf-ae0d-9e2347b6e726"]
for option_id in choice["optionOrder"]:
    var option: Dictionary = choice["options"][option_id]
    print(option_id, " ", option["text"]["textRef"])
# Resolve each text and bind its option_id to a Button's pressed signal.
var branch: Dictionary = story["execution"]["nodes"]["c1c3c372-0a73-4cd0-851d-ede59d5709bb"]
var gold := 10 # Repeat with 2.
var next: Dictionary = branch["whenTrue"] if gold >= branch["condition"]["right"]["value"]["value"] else branch["whenFalse"]
print(next["nodeRef"])

4 · Associer vos propres images

Cet extrait complémentaire suppose que le dialogue courant se trouve dans un objet nommé node et que les éléments d’interface cités en commentaire existent. En C++ et MonoGame, speakerRef a déjà été lu dans SpeakerId ou speakerId. La clé est le véritable identifiant de Mira ; le nom et l’emplacement de l’image dépendent de votre jeu. Insérez les lignes aux endroits indiqués.

# Put mira.png at res://portraits/mira.png and add a TextureRect named Portrait.
var portraits = {"807b2957-7bab-4a28-83a4-1f3d1589bbc2": preload("res://portraits/mira.png")}
# node is the current dialogue dictionary, not a Godot scene node.
$Portrait.texture = portraits.get(node.get("speakerRef", ""))

Retrouvez le nom du personnage avec content.characters[speakerRef].nameTextRef, comme pour un texte de dialogue. Si aucune image n’est associée, masquez l’ancien portrait ou affichez une image de remplacement. Les images ne sont pas choisies selon la langue.

Utiliser les références d'image de l'exportation complète

5 · Inclure les fichiers dans le jeu distribué

Avec FileAccess, conservez le JSON brut dans l’export : utilisez Keep File si cette option est disponible, sinon le filtre d’export des fichiers hors ressources adapté. Pour les images, utilisez des ressources Texture2D importées ou incluez explicitement les fichiers PNG originaux. Testez aussi une version exportée du jeu.

Vérifiez votre résultat

1. Les salutations en anglais et en allemand s'affichent correctement; une langue non disponible revient à l'anglais.
2. Après avoir ajouté la progression, testez les deux réponses, 10 puis 2 pièces d’or, le retour de la sous-histoire et End.
3. Lancez le jeu compilé en dehors du dossier du projet. Les fichiers JSON, les polices et les portraits doivent y être accessibles aussi.

Documentation officielle

Documentation des API et de la configuration utilisées :

• FileAccess et les fichiers inclus dans le jeu
• Analyse JSON
• Signaux du bouton